mirror of
https://github.com/PhotonVision/photonvision
synced 2026-06-19 00:41:41 +00:00
e9006a2803
Co-authored-by: Copilot <175728472+Copilot@users.noreply.github.com> Co-authored-by: Ryanforce08 <rradtke1208@gmail.com> Co-authored-by: PJ Reiniger <pj.reiniger@gmail.com> Co-authored-by: Jade Turner <spacey-sooty@proton.me> Co-authored-by: Matt Morley <matthew.morley.ca@gmail.com>
88 lines
3.1 KiB
Groovy
88 lines
3.1 KiB
Groovy
apply plugin: 'org.photonvision.tools.WpilibTools'
|
|
|
|
import java.nio.file.Path
|
|
|
|
ext.licenseFile = file("$rootDir/LICENSE")
|
|
ext.externalLicensesFolder = file("$rootDir/ExternalLicenses")
|
|
apply from: "${rootDir}/shared/common.gradle"
|
|
|
|
wpilibTools.deps.wpilibVersion = wpilibVersion
|
|
|
|
def nativeConfigName = 'wpilibNatives'
|
|
configurations {
|
|
wpilibNatives
|
|
}
|
|
def nativeTasks = wpilibTools.createExtractionTasks {
|
|
configurationName = nativeConfigName
|
|
}
|
|
|
|
nativeTasks.addToSourceSetResources(sourceSets.main)
|
|
|
|
dependencies {
|
|
wpilibNatives project(path: ':photon-targeting', configuration: 'wpilibNatives')
|
|
wpilibNatives wpilibTools.deps.wpilib("wpimath")
|
|
wpilibNatives wpilibTools.deps.wpilib("wpinet")
|
|
wpilibNatives wpilibTools.deps.wpilib("wpiutil")
|
|
wpilibNatives wpilibTools.deps.wpilib("datalog")
|
|
wpilibNatives wpilibTools.deps.wpilib("ntcore")
|
|
wpilibNatives wpilibTools.deps.wpilib("cscore")
|
|
wpilibNatives wpilibTools.deps.wpilib("apriltag")
|
|
wpilibNatives wpilibTools.deps.wpilib("hal")
|
|
wpilibNatives wpilibTools.deps.wpilibOpenCv(openCVversion)
|
|
|
|
// These stay as implementation dependencies since they don't have native code that gets packaged
|
|
implementation 'org.zeroturnaround:zt-zip:1.14'
|
|
implementation "org.xerial:sqlite-jdbc:3.41.0.0"
|
|
implementation 'com.diozero:diozero-core:1.4.1'
|
|
implementation 'com.github.oshi:oshi-core:6.9.1'
|
|
|
|
// The JNI libraries use wpilibNatives, the java libraries use implementation
|
|
if (jniPlatform == "linuxarm64") {
|
|
wpilibNatives("org.photonvision:rknn_jni-jni:$rknnVersion:$jniPlatform") {
|
|
transitive = false
|
|
}
|
|
wpilibNatives("org.photonvision:tflite_jni-jni:$tfliteVersion:$jniPlatform") {
|
|
transitive = false
|
|
}
|
|
wpilibNatives("org.photonvision:photon-libcamera-gl-driver-jni:$libcameraDriverVersion:$jniPlatform") {
|
|
transitive = false
|
|
}
|
|
}
|
|
|
|
if (jniPlatform == "linuxx86-64") {
|
|
wpilibNatives("org.photonvision:tflite_jni-jni:$tfliteVersion:$jniPlatform") {
|
|
transitive = false
|
|
}
|
|
}
|
|
|
|
implementation("org.photonvision:rknn_jni-java:$rknnVersion") {
|
|
transitive = false
|
|
}
|
|
|
|
implementation("org.photonvision:tflite_jni-java:$tfliteVersion") {
|
|
transitive = false
|
|
}
|
|
|
|
implementation "org.photonvision:photon-libcamera-gl-driver-java:$libcameraDriverVersion"
|
|
|
|
implementation "org.photonvision:photon-mrcal-java:$mrcalVersion"
|
|
|
|
wpilibNatives("org.photonvision:photon-mrcal-jni:$mrcalVersion:$jniPlatform") {
|
|
transitive = false
|
|
}
|
|
|
|
testImplementation group: 'org.junit-pioneer' , name: 'junit-pioneer', version: '2.2.0'
|
|
}
|
|
|
|
task writeCurrentVersion {
|
|
doLast {
|
|
def versionFileIn = file("${rootDir}/shared/PhotonVersion.java.in")
|
|
writePhotonVersionFile(versionFileIn, Path.of("$buildDir", "generated", "java", "org", "photonvision", "PhotonVersion.java"),
|
|
versionString)
|
|
}
|
|
}
|
|
// https://github.com/wpilibsuite/allwpilib/blob/main/wpilibj/build.gradle#L52
|
|
sourceSets.main.java.srcDir "${buildDir}/generated/java/"
|
|
|
|
compileJava.dependsOn writeCurrentVersion
|