allwpilib/shared/opencv.gradle

if (project.hasProperty('useCpp') && project.useCpp) {
    model {
        binaries {
            withType(NativeBinarySpec).all {
                def binary = it
                project.sharedCvConfigs.each {
                    if (binary.component.name == it.key) {
                        nativeUtils.useRequiredLibrary(binary, 'opencv_shared')
                    }
                }
                project.staticCvConfigs.each {
                    if (binary.component.name == it.key) {
                        nativeUtils.useRequiredLibrary(binary, 'opencv_static')
                    }
                }
            }
        }
    }
}

if (project.hasProperty('useJava') && project.useJava) {
    dependencies {
        implementation libs.thirdparty.opencv
        if (!project.hasProperty('skipDev') || !project.skipDev) {
            devImplementation libs.thirdparty.opencv
        }
        if (project.hasProperty('useDocumentation') && project.useDocumentation) {
            javaSource(variantOf(libs.thirdparty.opencv) { classifier("sources") })
        }
    }
}