load("@rules_cc//cc:defs.bzl", "cc_binary", "cc_library", "cc_test")
load("//shared/bazel/rules:packaging.bzl", "package_binary_cc_project")
load("//shared/bazel/rules/gen:gen-resources.bzl", "generate_resources")
load("//shared/bazel/rules/gen:gen-version-file.bzl", "generate_version_file")

generate_version_file(
    name = "generate-version",
    output_file = "WPILibVersion.cpp",
    template = "src/main/generate/WPILibVersion.cpp.in",
)

generate_resources(
    name = "generate-resources",
    namespace = "sysid",
    prefix = "SYSID",
    resource_files = glob(["src/main/native/resources/*"]),
)

cc_library(
    name = "sysid-lib",
    srcs = glob(
        ["src/main/native/cpp/**/*.cpp"],
        exclude = ["src/main/native/cpp/Main.cpp"],
    ) + [
        ":generate-resources",
        ":generate-version",
    ],
    hdrs = glob(["src/main/native/include/**"]),
    strip_include_prefix = "src/main/native/include",
    deps = [
        "//datalog",
        "//glass",
        "//wpinet",
    ],
)

cc_binary(
    name = "sysid",
    srcs = ["src/main/native/cpp/Main.cpp"],
    linkopts = select({
        "@platforms//os:windows": ["-SUBSYSTEM:WINDOWS"],
        "//conditions:default": [],
    }),
    deps = ["sysid-lib"],
)

cc_test(
    name = "sysid-test",
    size = "medium",
    srcs = glob(["src/test/native/cpp/**"]),
    tags = [
        "no-asan",
    ],
    deps = [
        ":sysid-lib",
        "//thirdparty/googletest",
    ],
)

package_binary_cc_project(
    name = "sysid",
    maven_artifact_name = "SysId",
    maven_group_id = "org.wpilib.tools",
)