plugins {
    id 'java'
    id 'application'
    id 'com.github.johnrengelman.shadow' version '2.0.3' apply false
}

ext {
    useJava = true
    useCpp = false
    skipDev = true
}

apply from: "${rootDir}/shared/opencv.gradle"

mainClassName = 'edu.wpi.first.wpilibj.test.AntJunitLanucher'

apply plugin: 'com.github.johnrengelman.shadow'

repositories {
    mavenCentral()
}

dependencies {
    compile project(':wpilibj')
    compile files(project(':wpilibj').sourceSets.test.output)
    compile project(':hal')
    compile project(':wpiutil')
    compile project(':ntcore')
    compile project(':cscore')
    compile project(':cameraserver')
    compile 'junit:junit:4.11'
    compile 'com.googlecode.junit-toolbox:junit-toolbox:2.0'
    compile 'org.apache.ant:ant:1.9.4'
    compile 'org.apache.ant:ant-junit:1.9.4'
}

build.dependsOn shadowJar

def testOutputFolder = file("${project(':').buildDir}/integrationTestFiles")

task copyWpilibJIntegrationTestJarToOutput(type: Copy) {
    destinationDir testOutputFolder
    dependsOn shadowJar
    inputs.file shadowJar.archivePath
    from(shadowJar) {
        into 'java'
    }
}

build.dependsOn copyWpilibJIntegrationTestJarToOutput