mirror of
https://github.com/wpilibsuite/allwpilib
synced 2026-06-21 01:01:43 +00:00
17b363f3b4
To publish the simulation zip, run ./gradlew publish -PmakeSim Targeting Ubuntu 14.04 and 15.10 for now, with 14.04 being the currently best supported. Two scripts have been drafted for installing, for 14.04 and 15.10 It currently publishes to ~/releases/maven/development/simulation There is a known bug that gz_msgs for 15.10 must be built using protobuf 2.6, which is not the default on 14.04. Change-Id: I6cccd601671553d30fd05bbbc79c2b7dc1efbf1d
83 lines
2.5 KiB
Groovy
83 lines
2.5 KiB
Groovy
sourceSets {
|
|
sim
|
|
}
|
|
|
|
dependencies {
|
|
simCompile sourceSets.shared.output
|
|
simCompile project(':simulation:JavaGazebo')
|
|
simCompile 'edu.wpi.first.wpilib.networktables.java:NetworkTables:3.0.0-SNAPSHOT:desktop'
|
|
simRuntime "edu.wpi.first.wpilib.networktables.java:NetworkTables:3.0.0-SNAPSHOT:desktop"
|
|
}
|
|
|
|
task wpilibjSimJar(type: Jar, dependsOn: simClasses) {
|
|
description = 'Creates the WPILibJSimulation Jar'
|
|
group = 'WPILib Simulation'
|
|
def addClasspath = { classpath ->
|
|
classpath.files.findAll { it.exists() }.each {
|
|
if (file(it).directory) {
|
|
from it
|
|
} else {
|
|
from zipTree(it.path)
|
|
}
|
|
}
|
|
}
|
|
|
|
addClasspath sourceSets.shared.runtimeClasspath
|
|
addClasspath sourceSets.sim.runtimeClasspath
|
|
|
|
from sourceSets.sim.output.classesDir
|
|
from sourceSets.shared.output.classesDir
|
|
baseName 'wpilibjSimulation'
|
|
}
|
|
|
|
task wpilibjSimSources(type: Jar, dependsOn: simClasses) {
|
|
description = 'Creates the wpilibjSimulation sources jar for the maven publishing routine'
|
|
group = 'WPILib'
|
|
classifier = 'sources'
|
|
from sourceSets.sim.allJava
|
|
from sourceSets.shared.allJava
|
|
}
|
|
|
|
task wpilibjSimJavadoc(type: Javadoc) {
|
|
description = 'Generates javadoc for the simulation components'
|
|
group = 'WPILib'
|
|
source sourceSets.sim.allJava, sourceSets.shared.allJava
|
|
classpath = files([sourceSets.sim.compileClasspath, sourceSets.shared.compileClasspath])
|
|
}
|
|
|
|
task wpilibjSimJavadocJar(type: Jar, dependsOn: wpilibjSimJavadoc) {
|
|
description = 'Creates the wpilibjSimulation javadoc jar for the maven publishing routine'
|
|
group = 'WPILib'
|
|
classifier = 'javadoc'
|
|
from wpilibjSimJavadoc.destinationDir
|
|
}
|
|
|
|
// Maven publishing configuration
|
|
publishing {
|
|
publications {
|
|
wpilibjSim(MavenPublication) {
|
|
artifact wpilibjSimJar
|
|
artifact(wpilibjSimSources) {
|
|
classifier = "sources"
|
|
}
|
|
artifact(wpilibjSimJavadocJar) {
|
|
classifier "javadoc"
|
|
}
|
|
|
|
groupId 'edu.wpi.first.wpilibj'
|
|
artifactId 'wpilibJavaSim'
|
|
version '0.1.0-SNAPSHOT'
|
|
}
|
|
}
|
|
}
|
|
|
|
//we need to move the simulation jars to the install directory
|
|
task copyJars(type: Copy) {
|
|
description = 'copy wpilibj simulation jar to make simulation zip'
|
|
group = 'WPILib Simulation'
|
|
from wpilibjSimJar.archivePath
|
|
into "$simulationInstallDir/jar"
|
|
}
|
|
|
|
build.dependsOn wpilibjSimJar
|