mirror of
https://github.com/wpilibsuite/allwpilib
synced 2026-06-19 00:41:43 +00:00
af7d68e993
This lets us remove the unmaintained StackWalker library and its hacky upstream_utils script. @Gold856 reported that StackWalker gives blank stacktraces: https://discord.com/channels/176186766946992128/368993897495527424/1261940029287301150. They also reported an earlier version of this PR giving the following stacktrace instead: ``` D:\allwpilib\developerRobot\src\main\native\cpp\Robot.cpp(18): developerRobotCpp!Robot::RobotInit+0xB6 D:\allwpilib\wpilibc\src\main\native\cpp\TimedRobot.cpp(22): wpilibcd!frc::TimedRobot::StartCompetition+0x4F D:\allwpilib\wpilibc\src\main\native\include\frc\RobotBase.h(36): developerRobotCpp!frc::impl::RunRobot<Robot>+0xC8 D:\allwpilib\wpilibc\src\main\native\include\frc\RobotBase.h(106): developerRobotCpp!frc::StartRobot<Robot>+0x17E D:\allwpilib\developerRobot\src\main\native\cpp\Robot.cpp(60): developerRobotCpp!main+0xB D:\a\_work\1\s\src\vctools\crt\vcstartup\src\startup\exe_common.inl(79): developerRobotCpp!invoke_main+0x39 D:\a\_work\1\s\src\vctools\crt\vcstartup\src\startup\exe_common.inl(288): developerRobotCpp!__scrt_common_main_seh+0x132 D:\a\_work\1\s\src\vctools\crt\vcstartup\src\startup\exe_common.inl(331): developerRobotCpp!__scrt_common_main+0xE D:\a\_work\1\s\src\vctools\crt\vcstartup\src\startup\exe_main.cpp(17): developerRobotCpp!mainCRTStartup+0xE KERNEL32!BaseThreadInitThunk+0x1D ntdll!RtlUserThreadStart+0x28 ```
91 lines
2.9 KiB
CMake
91 lines
2.9 KiB
CMake
project(commandsv2)
|
|
|
|
include(SubDirList)
|
|
include(CompileWarnings)
|
|
include(AddTest)
|
|
|
|
if(WITH_JAVA)
|
|
include(UseJava)
|
|
|
|
file(GLOB_RECURSE JAVA_SOURCES src/main/java/*.java src/generated/main/java/*.java)
|
|
file(GLOB AVAJE_JARS "${WPILIB_BINARY_DIR}/wpiutil/thirdparty/avaje/*.jar")
|
|
add_jar(
|
|
commandsv2_jar
|
|
${JAVA_SOURCES}
|
|
INCLUDE_JARS
|
|
hal_jar
|
|
ntcore_jar
|
|
${AVAJE_JARS}
|
|
cscore_jar
|
|
cameraserver_jar
|
|
wpimath_jar
|
|
wpiunits_jar
|
|
wpiutil_jar
|
|
wpilibj_jar
|
|
datalog_jar
|
|
wpiannotations_jar
|
|
OUTPUT_NAME commandsv2
|
|
OUTPUT_DIR ${WPILIB_BINARY_DIR}/${java_lib_dest}
|
|
)
|
|
set_property(TARGET commandsv2_jar PROPERTY FOLDER "java")
|
|
|
|
install_jar(commandsv2_jar DESTINATION ${java_lib_dest})
|
|
install_jar_exports(
|
|
TARGETS commandsv2_jar
|
|
FILE commandsv2_jar.cmake
|
|
DESTINATION share/commandsv2
|
|
)
|
|
endif()
|
|
|
|
if(WITH_JAVA_SOURCE)
|
|
include(UseJava)
|
|
include(CreateSourceJar)
|
|
add_source_jar(
|
|
commandsv2_src_jar
|
|
BASE_DIRECTORIES
|
|
${CMAKE_CURRENT_SOURCE_DIR}/src/main/java
|
|
${CMAKE_CURRENT_SOURCE_DIR}/src/generated/main/java
|
|
OUTPUT_NAME commandsv2-sources
|
|
OUTPUT_DIR ${WPILIB_BINARY_DIR}/${java_lib_dest}
|
|
)
|
|
set_property(TARGET commandsv2_src_jar PROPERTY FOLDER "java")
|
|
|
|
install_jar(commandsv2_src_jar DESTINATION ${java_lib_dest})
|
|
endif()
|
|
|
|
file(
|
|
GLOB_RECURSE commandsv2_native_src
|
|
src/main/native/cpp/*.cpp
|
|
src/generated/main/native/cpp/*.cpp
|
|
)
|
|
add_library(commandsv2 ${commandsv2_native_src})
|
|
set_target_properties(commandsv2 PROPERTIES DEBUG_POSTFIX "d")
|
|
set_property(TARGET commandsv2 PROPERTY FOLDER "libraries")
|
|
|
|
target_compile_features(commandsv2 PUBLIC cxx_std_23)
|
|
wpilib_target_warnings(commandsv2)
|
|
target_link_libraries(commandsv2 wpilibc)
|
|
|
|
target_include_directories(
|
|
commandsv2
|
|
PUBLIC
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/main/native/include>
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/generated/main/native/include>
|
|
$<INSTALL_INTERFACE:${include_dest}/commandsv2>
|
|
)
|
|
|
|
install(TARGETS commandsv2 EXPORT commandsv2)
|
|
export(TARGETS commandsv2 FILE commandsv2.cmake NAMESPACE commandsv2::)
|
|
install(DIRECTORY src/main/native/include/ DESTINATION "${include_dest}/commandsv2")
|
|
install(DIRECTORY src/generated/main/native/include/ DESTINATION "${include_dest}/commandsv2")
|
|
|
|
configure_file(commandsv2-config.cmake.in ${WPILIB_BINARY_DIR}/commandsv2-config.cmake)
|
|
install(FILES ${WPILIB_BINARY_DIR}/commandsv2-config.cmake DESTINATION share/commandsv2)
|
|
install(EXPORT commandsv2 DESTINATION share/commandsv2)
|
|
|
|
if(WITH_TESTS)
|
|
wpilib_add_test(commandsv2 src/test/native/cpp)
|
|
target_include_directories(commandsv2_test PRIVATE src/test/native/include)
|
|
target_link_libraries(commandsv2_test commandsv2 googletest)
|
|
endif()
|