allwpilib/simulation/adx_gyro_accelerometer/build.gradle

description = "A simulation library for the ADXL345 I2C and SPI Accelerometer, ADXL362 SPI Accelerometer, and ADXRS450 SPI Gyro"

apply plugin: 'edu.wpi.first.NativeUtils'
apply plugin: 'cpp'


if (!project.hasProperty('onlyAthena')) {
    ext.skipAthena = true

    apply from: "../../config.gradle"


    model {
        dependencyConfigs {
            wpiutil(DependencyConfig) {
                groupId = 'edu.wpi.first.wpiutil'
                artifactId = 'wpiutil-cpp'
                headerClassifier = 'headers'
                ext = 'zip'
                version = '3.+'
                sharedConfigs = [ halsim_adx_gyro_accelerometer: [] ]
            }
        }
        exportsConfigs {
            halsim_adx_gyro_accelerometer(ExportsConfig) {
                x86ExcludeSymbols = [ '_CT??_R0?AV_System_error', '_CT??_R0?AVexception', '_CT??_R0?AVfailure',
                                      '_CT??_R0?AVbad_cast',
                                      '_CT??_R0?AVruntime_error', '_CT??_R0?AVsystem_error', '_CTA5?AVfailure',
                                      '_TI5?AVfailure' ]
                x64ExcludeSymbols = [ '_CT??_R0?AV_System_error', '_CT??_R0?AVexception', '_CT??_R0?AVfailure',
                                      '_CT??_R0?AVbad_cast',
                                      '_CT??_R0?AVruntime_error', '_CT??_R0?AVsystem_error', '_CTA5?AVfailure',
                                      '_TI5?AVfailure' ]
            }
        }
        components {
            halsim_adx_gyro_accelerometer(NativeLibrarySpec) {
                sources {
                    cpp {
                        source {
                            srcDirs = [ 'src/main/native/cpp' ]
                            includes = ["**/*.cpp"]
                        }
                        exportedHeaders {
                            srcDirs = ["src/main/native/include"]
                        }
                    }
                }
            }
        }

        binaries {
            all {
                project(':hal').addHalCompilerArguments(it)
                project(':hal').addHalToLinker(it)
            }
        }
    }
    apply from: 'publish.gradle'
}