mirror of
https://github.com/wpilibsuite/allwpilib
synced 2026-06-19 00:41:43 +00:00
bf75c03218
Explicitly list required components when using FindJava and FindJNI Consolidate find_package calls for Java, JNI, and OpenCV into the root CMakeLists.txt file Remove references to main_lib_dest Install missing generated headers Flatten some if statements Use LinkMacOSGUI macro instead of hand rolling it Stop installing OpenCV libraries and an extra ntcorejni library; OpenCV JAR will still be installed to make it easy to use Only print platform version on Windows Prevent GUI modules from being built when wpimath is off, which would otherwise cause a build failure Simplify build configuration checks Clean up fieldImages JAR creation Place built JARs in the same subdir as installed JARs Remove unnecessary JAR includes Remove extra directories in target_include_directories Improve CMake docs
95 lines
3.3 KiB
CMake
95 lines
3.3 KiB
CMake
project(cameraserver)
|
|
|
|
include(CompileWarnings)
|
|
include(AddTest)
|
|
|
|
# Java bindings
|
|
if(WITH_JAVA)
|
|
include(UseJava)
|
|
|
|
#find JAR file, copy it locally
|
|
set(OPENCV_JAVA_INSTALL_DIR ${OpenCV_INSTALL_PATH}/share/java/opencv4)
|
|
|
|
find_file(
|
|
OPENCV_JAR_FILE
|
|
NAMES opencv-${OpenCV_VERSION_MAJOR}${OpenCV_VERSION_MINOR}${OpenCV_VERSION_PATCH}.jar
|
|
PATHS
|
|
${OPENCV_JAVA_INSTALL_DIR}
|
|
${OpenCV_INSTALL_PATH}/bin
|
|
${OpenCV_INSTALL_PATH}/share/java
|
|
${OpenCV_INSTALL_PATH}/share/OpenCV/java
|
|
NO_DEFAULT_PATH
|
|
)
|
|
|
|
file(GLOB_RECURSE JAVA_SOURCES src/main/java/*.java)
|
|
|
|
add_jar(
|
|
cameraserver_jar
|
|
${JAVA_SOURCES}
|
|
INCLUDE_JARS wpiutil_jar cscore_jar ntcore_jar ${OPENCV_JAR_FILE}
|
|
OUTPUT_NAME cameraserver
|
|
OUTPUT_DIR ${WPILIB_BINARY_DIR}/${java_lib_dest}
|
|
)
|
|
set_property(TARGET cameraserver_jar PROPERTY FOLDER "java")
|
|
|
|
install_jar(cameraserver_jar DESTINATION ${java_lib_dest})
|
|
install_jar_exports(
|
|
TARGETS cameraserver_jar
|
|
FILE cameraserver_jar.cmake
|
|
DESTINATION share/cameraserver
|
|
)
|
|
endif()
|
|
|
|
if(WITH_JAVA_SOURCE)
|
|
include(UseJava)
|
|
file(GLOB CAMERASERVER_SOURCES src/main/java/edu/wpi/first/cameraserver/*.java)
|
|
file(GLOB VISION_SOURCES src/main/java/edu/wpi/first/vision/*.java)
|
|
add_jar(
|
|
cameraserver_src_jar
|
|
RESOURCES
|
|
NAMESPACE "edu/wpi/first/cameraserver" ${CAMERASERVER_SOURCES}
|
|
NAMESPACE "edu/wpi/first/vision" ${VISION_SOURCES}
|
|
OUTPUT_NAME cameraserver-sources
|
|
OUTPUT_DIR ${WPILIB_BINARY_DIR}/${java_lib_dest}
|
|
)
|
|
|
|
get_property(CAMERASERVER_SRC_JAR_FILE TARGET cameraserver_src_jar PROPERTY JAR_FILE)
|
|
install(FILES ${CAMERASERVER_SRC_JAR_FILE} DESTINATION "${java_lib_dest}")
|
|
|
|
set_property(TARGET cameraserver_src_jar PROPERTY FOLDER "java")
|
|
endif()
|
|
|
|
file(GLOB_RECURSE cameraserver_native_src src/main/native/cpp/*.cpp)
|
|
add_library(cameraserver ${cameraserver_native_src})
|
|
set_target_properties(cameraserver PROPERTIES DEBUG_POSTFIX "d")
|
|
target_include_directories(
|
|
cameraserver
|
|
PUBLIC
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/main/native/include>
|
|
$<INSTALL_INTERFACE:${include_dest}/cameraserver>
|
|
)
|
|
wpilib_target_warnings(cameraserver)
|
|
target_link_libraries(cameraserver PUBLIC ntcore cscore wpiutil ${OpenCV_LIBS})
|
|
|
|
set_property(TARGET cameraserver PROPERTY FOLDER "libraries")
|
|
|
|
install(TARGETS cameraserver EXPORT cameraserver)
|
|
export(TARGETS cameraserver FILE cameraserver.cmake NAMESPACE cameraserver::)
|
|
install(DIRECTORY src/main/native/include/ DESTINATION "${include_dest}/cameraserver")
|
|
|
|
configure_file(cameraserver-config.cmake.in ${WPILIB_BINARY_DIR}/cameraserver-config.cmake)
|
|
install(FILES ${WPILIB_BINARY_DIR}/cameraserver-config.cmake DESTINATION share/cameraserver)
|
|
install(EXPORT cameraserver DESTINATION share/cameraserver)
|
|
|
|
file(GLOB multiCameraServer_src multiCameraServer/src/main/native/cpp/*.cpp)
|
|
add_executable(multiCameraServer ${multiCameraServer_src})
|
|
wpilib_target_warnings(multiCameraServer)
|
|
target_link_libraries(multiCameraServer cameraserver)
|
|
|
|
set_property(TARGET multiCameraServer PROPERTY FOLDER "examples")
|
|
|
|
if(WITH_TESTS)
|
|
wpilib_add_test(cameraserver src/test/native/cpp)
|
|
target_link_libraries(cameraserver_test cameraserver gtest)
|
|
endif()
|