mirror of
https://github.com/wpilibsuite/allwpilib
synced 2026-06-19 00:41:43 +00:00
bf75c03218
Explicitly list required components when using FindJava and FindJNI Consolidate find_package calls for Java, JNI, and OpenCV into the root CMakeLists.txt file Remove references to main_lib_dest Install missing generated headers Flatten some if statements Use LinkMacOSGUI macro instead of hand rolling it Stop installing OpenCV libraries and an extra ntcorejni library; OpenCV JAR will still be installed to make it easy to use Only print platform version on Windows Prevent GUI modules from being built when wpimath is off, which would otherwise cause a build failure Simplify build configuration checks Clean up fieldImages JAR creation Place built JARs in the same subdir as installed JARs Remove unnecessary JAR includes Remove extra directories in target_include_directories Improve CMake docs
111 lines
3.7 KiB
CMake
111 lines
3.7 KiB
CMake
project(hal)
|
|
|
|
include(CompileWarnings)
|
|
include(AddTest)
|
|
|
|
file(
|
|
GLOB hal_shared_native_src
|
|
src/main/native/cpp/*.cpp
|
|
src/main/native/cpp/cpp/*.cpp
|
|
src/main/native/cpp/handles/*.cpp
|
|
)
|
|
file(GLOB_RECURSE hal_sim_native_src src/main/native/sim/*.cpp)
|
|
add_library(hal ${hal_shared_native_src} ${hal_sim_native_src})
|
|
wpilib_target_warnings(hal)
|
|
set_target_properties(hal PROPERTIES DEBUG_POSTFIX "d")
|
|
set_target_properties(hal PROPERTIES OUTPUT_NAME "wpiHal")
|
|
|
|
target_include_directories(
|
|
hal
|
|
PUBLIC
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/main/native/include>
|
|
$<INSTALL_INTERFACE:${include_dest}/hal>
|
|
)
|
|
|
|
target_include_directories(
|
|
hal
|
|
PUBLIC
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/generated/main/native/include>
|
|
$<INSTALL_INTERFACE:${include_dest}/hal>
|
|
)
|
|
target_link_libraries(hal PUBLIC wpiutil)
|
|
|
|
set_property(TARGET hal PROPERTY FOLDER "libraries")
|
|
|
|
install(TARGETS hal EXPORT hal)
|
|
export(TARGETS hal FILE hal.cmake NAMESPACE hal::)
|
|
install(DIRECTORY src/main/native/include/ DESTINATION "${include_dest}/hal")
|
|
install(DIRECTORY src/generated/main/native/include/ DESTINATION "${include_dest}/hal")
|
|
|
|
configure_file(hal-config.cmake.in ${WPILIB_BINARY_DIR}/hal-config.cmake)
|
|
install(FILES ${WPILIB_BINARY_DIR}/hal-config.cmake DESTINATION share/hal)
|
|
install(EXPORT hal DESTINATION share/hal)
|
|
|
|
# Java bindings
|
|
if(WITH_JAVA)
|
|
include(UseJava)
|
|
|
|
file(GLOB_RECURSE hal_shared_jni_src src/main/native/cpp/jni/*.cpp)
|
|
|
|
file(GLOB_RECURSE JAVA_SOURCES src/main/java/*.java src/generated/main/java/*.java)
|
|
set(CMAKE_JNI_TARGET true)
|
|
|
|
add_jar(
|
|
hal_jar
|
|
${JAVA_SOURCES}
|
|
INCLUDE_JARS wpiutil_jar
|
|
OUTPUT_NAME wpiHal
|
|
OUTPUT_DIR ${WPILIB_BINARY_DIR}/${java_lib_dest}
|
|
GENERATE_NATIVE_HEADERS hal_jni_headers
|
|
)
|
|
set_property(TARGET hal_jar PROPERTY FOLDER "java")
|
|
|
|
install_jar(hal_jar DESTINATION ${java_lib_dest})
|
|
install_jar_exports(TARGETS hal_jar FILE hal_jar.cmake DESTINATION share/hal)
|
|
|
|
add_library(haljni ${hal_shared_jni_src})
|
|
set_target_properties(haljni PROPERTIES OUTPUT_NAME "wpiHaljni")
|
|
|
|
wpilib_target_warnings(haljni)
|
|
target_link_libraries(haljni PUBLIC hal wpiutil)
|
|
|
|
set_property(TARGET haljni PROPERTY FOLDER "libraries")
|
|
|
|
target_link_libraries(haljni PRIVATE hal_jni_headers)
|
|
add_dependencies(haljni hal_jar)
|
|
|
|
install(TARGETS haljni EXPORT haljni)
|
|
export(TARGETS haljni FILE haljni.cmake NAMESPACE haljni::)
|
|
endif()
|
|
|
|
if(WITH_JAVA_SOURCE)
|
|
include(UseJava)
|
|
file(GLOB HAL_SOURCES src/main/java/edu/wpi/first/hal/*.java src/generated/main/java/*.java)
|
|
file(GLOB HAL_CAN_SOURCES src/main/java/edu/wpi/first/hal/can/*.java)
|
|
file(GLOB HAL_SIMULATION_SOURCES src/main/java/edu/wpi/first/hal/simulation/*.java)
|
|
file(GLOB HAL_UTIL_SOURCES src/main/java/edu/wpi/first/hal/util/*.java)
|
|
add_jar(
|
|
hal_src_jar
|
|
RESOURCES
|
|
NAMESPACE "edu/wpi/first/hal" ${HAL_SOURCES}
|
|
NAMESPACE "edu/wpi/first/hal/can" ${HAL_CAN_SOURCES}
|
|
NAMESPACE
|
|
"edu/wpi/first/hal/communication"
|
|
src/main/java/edu/wpi/first/hal/communication/NIRioStatus.java
|
|
NAMESPACE "edu/wpi/first/hal/simulation" ${HAL_SIMULATION_SOURCES}
|
|
NAMESPACE "edu/wpi/first/hal/util" ${HAL_UTIL_SOURCES}
|
|
OUTPUT_NAME wpiHal-sources
|
|
OUTPUT_DIR ${WPILIB_BINARY_DIR}/${java_lib_dest}
|
|
)
|
|
|
|
get_property(HAL_SRC_JAR_FILE TARGET hal_src_jar PROPERTY JAR_FILE)
|
|
install(FILES ${HAL_SRC_JAR_FILE} DESTINATION "${java_lib_dest}")
|
|
|
|
set_property(TARGET hal_src_jar PROPERTY FOLDER "java")
|
|
endif()
|
|
|
|
if(WITH_TESTS)
|
|
wpilib_add_test(hal src/test/native/cpp)
|
|
target_link_libraries(hal_test hal gtest)
|
|
endif()
|